Der Methods-Typ

Der Methods-Typ hat die folgenden Felder:

data Methods =
  Methods { -- Konfigurationsoption abfragen
            cgetCmd     :: ObjectName -> ConfigID -> TclScript,

            -- eine List von Konfigurationen setzen
            csetCmd     :: ObjectName -> [ConfigOption] -> TclScript,

            -- das Objekt erzeugen
            createCmd   :: ObjectName -> ObjectKind -> ObjectName ->
                           ObjectID -> [ConfigOption] -> TclScript,

            -- das Objekt mit Tk's "pack geometry manager" packen
            -- für "nicht-Widgets" leer
            packCmd     :: ObjectName -> [PackOption] -> TclScript,

            -- das Objekt mit Tk's "grid geometry manager" packen
            -- für "nicht-Widgets" leer
            gridCmd     :: ObjectName -> [GridPackOption] -> TclScript,

            -- das Objekt zerstören
            destroyCmd  :: ObjectName -> TclScript,

            -- Events an dieses Objekt binden
            bindCmd     :: ObjectName -> BindTag -> [WishEvent] ->
                           EventInfoSet -> TclScript,

            -- Event-Bindung verwerfen
            unbindCmd   :: ObjectName -> BindTag -> [WishEvent] ->
                           TclScript,

             -- zum aufräumen bei der Zerstörung, i.d.R. leer
            cleanupCmd  :: ObjectID -> ObjectName -> TclScript }

Auf den Typ ObjectName möchte ich hier nicht weiter eingehen. Er wird durch die oben erwähnten GUIOBJECT-Konstruktoren automatisch erzeugt und enthält den Tcl-Pfad des entsprechenden Objektes. Es reicht zu wissen, daß er eine Instanz der Klasse Show ist und so auf den Tcl-Bezeichner des Objektes zugegriffen werden kann. Weiter wäre anzumerken, daß nicht für jedes Objekt tatsächlich alle obigen Parameter gebraucht werden. Dies ist vor allem Abhängig von der Art der Tk-Objekte (so braucht man z.B. das Vater-Objekte bei der Erzeugung nur zum Zugriff auf Text-Items).

• cgetCmd:
  Erzeugt ein Tcl-Skript, daß den Wert einer Konfigurationsoption eines Objektes abfragt. Da der korrespondierende Wert immer eine Instanz der Klasse GUIValue ist, die eine Read-Instanz voraussetzt, kann er immer parsiert und zurückgegeben werden.
  Beispiel (die Default-Methode):

  tkGetWidgetConfig :: ObjectName ->  -- Tcl-Pfad des Objektes
                       ConfigID ->    -- Tcl-Bezeichner der Konfiguration
                       TclScript
  tkGetWidgetConfig name cid = [(show name) ++ " cget -" ++ cid]

• csetCmd:
  Erzeugt ein Tcl-Skript, das eine Liste von Konfigurationen setzt. Der Typ ConfigOption ist einfach ein Tupel aus ConfigID (= String) und GUIVALUE.
  Beispiel (die Default-Methode):

  tkSetWidgetConfigs :: ObjectName ->       -- Tcl-Pfad des Objektes
                        [ConfigOption] ->   -- Liste der Konfigurationen
                        TclScript
  tkSetWidgetConfigs _ [] = []
  tkSetWidgetConfigs name args =
    [show name ++ " configure " ++ showConfigs args]

  Die Funktion showConfigs kann zur bequemen Ausgabe einer Liste von Konfigurationen in den korrespondierenden Tcl-String verwendet werden:

  showConfigs :: [(ConfigID, GUIVALUE)] -> String

• createCmd:
  Erzeugt ein Tcl-Skript, das das korrespondierende Tk-Objekt konstruiert. Die dabei übergebene Liste von Konfigurationen kann benutzt werden, um intern bestimmte vom Tk-Default abweichende Konfigurationen für dieses Objekt vorzudefinieren. Die im HTk-Konstruktor übergebenen Konfigurationen werden hier nicht verarbeitet (dies geht aus Gründen, die ich hier nicht näher erläutern will auch gar nicht).
  Beispiel (die Default-Methode):

  tkCreateWidget :: ObjectName ->   -- Tcl-Pfad des Vaterobjektes
                    ObjectKind ->   -- Objekttyp
                    ObjectName ->   -- Tcl-Pfad des Objektes
                    ObjectID ->     -- ID des Objektes auf HTk-Seite
                    [ConfigOption] -> TclScript
  tkCreateWidget _ kind name _ opts =
    [show kind ++ " " ++ show name ++ " " ++ showConfigs opts]

• packCmd:
  Erzeugt ein Tcl-Skript, das ein bereits auf Tk-Seite existierendes Widget mit dem pack geometry manager packt. Diese Methode wird man niemals überschreiben, denn das Packen eines Widgets ist auf Tk-Seite einheitlich. Für nicht-Widgets sollte das erzuegte Skript leer sein.
  Beispiel (die Default-Methode):

  tkPack :: ObjectName ->     -- Tcl-Pfad des Objektes
            [PackOption] ->   -- Liste der Optionen für den geometry manager
            TclScript
  tkPack name opts = ["pack " ++ show name ++ " " ++ showPackOptions opts]

• gridCmd:
  Erzeugt ein Tcl-Skript, das ein bereits auf Tk-Seite existierendes Widget mit dem grid geometry manager packt. Auch diese Methode wird man niemals überschreiben (das Packen eines Widgets ist auf Tk-Seite einheitlich). Für nicht-Widgets sollte das erzeugte Skript leer sein.
  Beispiel (die Default-Methode):

  tkGrid :: ObjectName ->        -- Tcl-Pfad des Objektes
            [GridPackOption] ->  -- Liste der Optionen für den geometry manager
            TclScript
  tkGrid name opts =
    ["grid " ++ show name ++ " " ++ showGridPackOptions opts]

• destroyCmd:
  Erzeugt ein Tcl-Skript, das ein Tk-Objekt zerstört.
  Beispiel (die Default-Methode):

  tkDestroyWidget :: ObjectName ->   -- Tcl-Pfad des Objektes
                     TclScript
  tkDestroyWidget name = ["destroy " ++ show name]

• bindCmd:
  Erzeugt ein Tcl-Skript, das Events an ein Tk-Objekt bindet. Da auch diese Methode niemals überschrieben werden muß, will ich hier darauf nicht weiter eingehen. Wichtig ist nur, daß die Show-Instanz des ObjectName den Tcl-Pfad des Objektes liefert, aber dies ist in HTk sowieso Konvention bzw. wird durch die Methoden zur Erzeugung der internen GUIOBJECT-Repräsentation sichergestellt. Zu bemerken wäre höchstens noch, daß wir uns für HTk auf einen vereinfachten Umgang mit den von Tcl zurückzugeben Event-Informationen (Position, Button, etc.) geeinigt haben, so daß hier immer dasselbe Event-Info-Set verwendet wird (auch dieser Typ muß daher hier nicht näher erläutert werden). Der WishEvent-Typ sollte von der Benutzerseite her bekannt sein.
  Beispiel (die Default-Methode):

  tkBindWidget :: ObjectName ->      -- Tcl-Pfad des Objektes
                  BindTag ->         -- historisch, rausnehmen !!
                  [WishEvent] ->     -- Liste der Events
                  EventInfoSet ->    -- Liste der zurückzugebenden
                                     -- Event-Informationen
                  TclScript
  tkBindWidget nm bindTag wishEvents eventInfoSet =
    let doBind = "bind " ++ show nm ++ " " ++
                 delimitString (foldr (\ event soFar -> showP event soFar)
                                      "" wishEvents) ++ " " ++
                 mkBoundCmdArg bindTag eventInfoSet
    in [doBind]

• unbindCmd:
  Erzeugt ein Tcl-Skript, daß Event-Bindungen (s.o.) rückgängig macht, d.h. auf Tcl-Seite für diese Events ein leeres Kommando bindet. Auch diese Methode wird niemals überschrieben werden müssen.
  Beispiel (die Default-Methode):

  tkUnbindWidget :: ObjectName ->
                    BindTag ->
                   [WishEvent] -> TclScript
  tkUnbindWidget nm bindTag wishEvents =
    let doUnBind = "bind " ++ show nm ++ " " ++
                   delimitString (foldr (\ event soFar -> showP event soFar)
                                        "" wishEvents) ++ " {}"
    in [doUnBind]

• cleanupCmd:
  Dieses Kommando ist zur Freigabe auf Tcl-Seite benutzter Ressourcen bei der Zerstörung eines Objektes vorgesehen. Bisher wird es jedoch nicht benutzt. Die default-Methode ist daher leer.