%{
#include <stdio.h>
int codeLines = 0, commentLines = 0, blankLines = 0;
int currCodeLine = 0, currCommentLine = 0;
%}
%option noyywrap
%x COMMENT
%x STRING
%%
"/*"		{ BEGIN COMMENT; currCommentLine = 1; }
<COMMENT>"*/"	{ BEGIN INITIAL; currCommentLine = 1; }
"\""		{ BEGIN STRING; currCodeLine = 1; }
<STRING>"\""	{ BEGIN INITIAL; currCodeLine = 1; }
<STRING>"\\\\"	{ currCodeLine = 1; }
<STRING>"\\\""	{ currCodeLine = 1; }
<STRING>"\n"	{ codeLines++; /* String-Fortsetzungszeile */
		  currCodeLine = 1;
		  currCommentLine = 0;
		}
<INITIAL,COMMENT>[ \t]	{ /* Blank, Tab ignorieren */ }
<INITIAL,STRING>.	{ currCodeLine = 1; }
<COMMENT>.	{ currCommentLine = 1; }
<INITIAL,COMMENT>"\n"	{
		  if(currCodeLine)
		      codeLines++;
		  else if(currCommentLine)
		  	  commentLines++;
		      else
		          blankLines++;
		  currCodeLine = 0;
		  currCommentLine = 0;
		}
	/* Die letzte Zeile muss mit einem Newline abgeschlossen sein. */
%%
int main() {
    yylex();
    printf(
      "%d Code-Zeilen, %d Nur-Kommentar-Zeilen, %d ganz leere Zeilen\n",
      codeLines, commentLines, blankLines);
}